Export List of User Mailbox with Size information in Lotus Domino ~ LazyExchangeAdmin

Export List of User Mailbox with Size information in Lotus Domino

One would think that there is a function in Domino Admin client to export a list of database with their corresponding size information. Well, as simple as the concept might be, there is no built in tool to do just that. If the mailbox quota/size statistics is crucial for your organization for capacity planning or just for record purposes, you can always leverage the LotusScript to export these information.

Note that in this example, it is expected that you are already familiar with using Lotus Notes Designer and LotusScript.

Create the Appplication
1. Create a blank application and place it in your "data" folder.
2. Create a Form and add a Button.

3. Add your code to the Button's click event.

================================
Sub Click(Source As Button)
   On Error Resume Next

   Dim oQuota As Integer
   Dim oWarning As Integer
   Dim oTotal As Integer
   Dim oTotalSize As Double

   Dim db As NotesDatabase
   Dim f As Integer
   f = Freefile
   Open "c:\DBlist.txt" For Output As #f

   Dim dbdir As New NotesDbDirectory("RSBDOM01/RSBPH")
   Set db = dbdir.GetFirstDatabase(DATABASE)
   Print #f, "Title" & Chr$(9) & "FileName" & Chr$(9) & "Size" & Chr$(9) & "Quota" & Chr$(9) & "Warning"
   While Not(db Is Nothing)
       If Instr(1,db.FilePath,"mail\",5)>0 Then
           Print "Getting Info: " & db.Title
           Print #f, db.Title & Chr$(9) & db.FileName & Chr$(9) & db.Size & Chr$(9) & db.SizeQuota & Chr$(9) & db.SizeWarning

           oTotal=oTotal+1
           oTotalSize=oTotalSize+db.size

           If db.size/1024 > db.SizeQuota Then
               oQuota=oQuota+1
           Elseif db.Size/1024 > db.SizeWarning Then
               oWarning=oWarning+1
           End If
       End If
       Set db = dbdir.GetNextDatabase
   Wend
   Print "Export Complete"
   Messagebox("Overquota: " & oQuota & Chr$(13) & Chr$(10) & "Warning: " & oWarning & Chr$(13) & Chr$(10) & "Normal: " & oTotal-oQuota-oWarning & Chr$(13) & Chr$(10) & "Total Mail Files: " & oTotal & Chr$(13) & Chr$(10) & "Total Size: " & Format(oTotalSize/1024,"Standard") & " KB")
   Close #f
End Sub

================================
4. Create a Frameset and add the Form to one of the Frames.
5. Set the Frameset to show once the Database is opened.